[ONScripter] 12. 복합 버튼 만들기 (최종수정 2010.10.26) 강의이야기 | Posted on 2010. 9. 6. 18:33
저번강의에 이어서, 이번 강의도 온스크립터에서의 버튼을 만드는 강의입니다.
1. exbtn
스프라이트를 사용, 복합 버튼을 설정합니다.
사용법은 "exbtn 스프라이트번호, 버튼번호, 스프라이트제어문자열"입니다.
마지막에 붙는 "스프라이트 제어 문자열"을 제외하고는 "spbtn"과 같습니다.
스프라이트번호 : 버튼으로 사용할 스프라이트의 번호를 설정합니다.
버튼번호 : 버튼 고유의 번호입니다.
스프라이트 제어 문자열 :
a. C스프라이트 번호 : 지정한 스프라이트 번호를 화면에 표시하지 않습니다.
b. P스프라이트 번호 : 지정한 스프라이트 번호를 화면에 표시합니다.
2. exbtn_d
exbtn를 사용할때 꼭 같이 사용해야하는 명령어입니다.
(라고 메뉴얼에 적혀있지만, 꼭 같이 사용하지 않으셔도 상관없습니다.)
1번에서 설명한 exbtn의 제어를 받지 않는 경우를 지정합니다.
다르게 말하면, 버튼위에 마우스가 없을경우를 지정하는 명령어입니다.
사용법은 "exbtn_d 스프라이트제어문자열" 입니다.
※ 이 명령어의 중요성은 아래의 샘플 스크립트에서 exbtn_d "P1P2P3C4C5C6"앞에 ;를 하신후 테스트해보세요.
마우스를 버튼에 가져다 대신 후 버튼밖으로 빼보세요.
그러면 이전 강의에서 만든 그 버튼을 그대로 다시 만들어 보겠습니다.
*define
rmenu "画像表示",windowerase ,"セーブ",save,"ロード",load,"選択肢まで進む",skip,"回想",lookback,"終了する",reset
transmode alpha
game
*start
*title
bg "Graphic/TITLEBG00.png", 1
lsp 1,":s/22,22,0;#808080 ＳＴＡＲＴ",245,330
lsp 2,":s/22,22,0;#808080 ＬＯＡＤ",245,360
lsp 3,":s/22,22,0;#808080 ＥＮＤ",245,390
lsp 4,":s/22,22,0;#FFFF00 ＳＴＡＲＴ",245,330
lsp 5,":s/22,22,0;#FFFF00 ＬＯＡＤ",245,360
lsp 6,":s/22,22,0;#FFFF00 ＥＮＤ",245,390
exbtn_d "P1P2P3C4C5C6"
exbtn 4,1,"C1P2P3P4C5C6S1,(Se/SE_CURSORMOVE.ogg)"
exbtn 5,2,"P1C2P3C4P5C6S1,(Se/SE_CURSORMOVE.ogg)"
exbtn 6,3,"P1P2C3C4C5P6S1,(Se/SE_CURSORMOVE.ogg)"
btnwait %0
if %0 == 0 goto *title
if %0 == -1 systemcall rmenu
if %0 == 1 csp -1:goto *prologue
if %0 == 2 systemcall load
if %0 == 3 end
goto *title
*prologue
bg "Bg/BGSP_15A.png", 1
lsp 1,"System/NAMEWIN.jpg",30,290
setwindow 30,350,20,23,26,26,0,2,20,1,1,"System/MSGWIN.jpg",30,325
なにか理由があったわけじゃない。\
이전 강의와는 다르게 스프라이트버튼이 많아졌습니다만, 기능은 이전강의에서 설명한 기능 그대로입니다.
(단, 하나의 차이점이라면 아래의 팁인 음원파일입니다.)
복합 버튼 명령어에 대한 설명은 이것으로 끝입니다.
버튼을 만드는데 어떤 명령어가 좋은지는 스크립트 제작자의 취향입니다.
딱히 이것이 좋다, 저것이 좋다는 없습니다.
명령어에 대한 설명을 가지고 하는 응용은 여러분들의 몫입니다.
※ 한가지팁.
스프라이트 제어 문자열에 S1을 추가하고 뒤에 음원파일의 주소를 넣을경우, 버튼에 마우스를 가져갔을때 음원이 재생되게됩니다.
예 : exbtn 4,1,"C1P2P3P4C5C6S1,(Se/SE_CURSORMOVE.ogg)"
작성자 Pure Ani
출 처 MPPC (미소녀 & PocketPC)
